メニューボタン
サポートチーム便り2026.11.25

悪用厳禁!?IBM i の稼働中の他のジョブの*LIBLを変更したい

Question

バッチジョブにおいて、ライブラリーが不足していてオブジェクトが存在しないためMSGW(メッセージ待ち)が発生しました。

MSGWになっているジョブに対し、外部からライブラリーを追加して、応答"R"でその箇所から処理を再開させたいと考えています。

稼働中の他のジョブに対してライブラリーリストを変更する方法はあるのでしょうか。

Answer

長時間のバッチ処理がMSGWで止まってしまった際、最初からやり直さずに不足しているライブラリーを追加してその場から再開させたいと考えるのは当然のことと存じます。

しかしながら、ADDLIBLEコマンドには「どのジョブに対して追加するか」を指定するJOBパラメーターが存在せず、常に「コマンドを実行している自身のジョブ」に対してのみ有効となる仕様となっています。

そのため、原則として外部から稼働中の別ジョブのライブラリーリストを変更することはできません。

一度ジョブを終了(中断)し、ライブラリーリストを正しく設定した上で再実行することを推奨いたします。

IBM i (AS/400)のライブラリーリストって何ですか?
https://www.e-bellnet.com/category/technology/1901/1901-74.html

さて、では実際にMSGWしているジョブに対し、割り込み操作のようなことはできないのでしょうか?

あくまで技術的に可能か検証したところ、事前準備を含め手間暇をかければ実現できるようです。

事前のプログラム組み込み等を条件として、「Call Job Interrupt Program (QWCJBITP) API」を利用し、実行中のジョブを一時的に中断させて指定したCL(ADDLIBLE等)を強制的に割り込み実行させる手法が存在します。

実現するための手順は以下の通りです。

  1. システム値の変更

    システム値「QALWJOBITP」を「1」に変更します。

    設定値「1」の説明:
    システムは,ユーザー定義出口プログラムを実行するためにジョブを中断することを許可します。

    コマンド:WRKSYSVAL QALWJOBITP
    OPT欄に「2=変更」を入れて、値を「1」に変更してください。

  2. 割り込みで実行させるCLの作成と登録(CL1:SETLIB_T)

    他のジョブに実行させたい内容のCLを作成します。

    ----- CL1サンプル -----------------------------
    PGM PARM(&EXITDTA &DTALEN)
    DCL VAR(&EXITDTA) TYPE(*CHAR) LEN(56)
    DCL VAR(&DTALEN)  TYPE(*CHAR) LEN(4)
    ADDLIBLE LIB(LIB_NAME) POSITION(*LAST)
    MONMSG MSGID(CPF2103)
    ENDPGM
    --------------------------------------------------

    ※『ADDLIBLE LIB(LIB_NAME) POSITION(*LAST)』の LIB_NAME 部分は、追加したいライブラリー名に変更してください。
    ※QGPLなど、対象ジョブのライブラリーリストに既に登録されているライブラリーにコンパイルしてください。

    次に、作成したプログラムを出口プログラムとして登録します。
    WRKREGINF EXITPNT(QIBM_QWC_JOBITPPGM) を実行
    →OPT欄に「8=出口プログラムの処理」を入れて実行
    →次の画面にてOPT欄に「1=追加」、出口プログラムに「SETLIB_T」、
    ライブラリーにコンパイル先のライブラリー名(この例ではQGPL)を入力して実行

  3. 割り込みを受け入れる側(対象ジョブ)の事前準備(CL2:ALW_INTJOB)

    MSGW中のジョブに対して、後から割り込みを許可するAPIを実行することはできません。

    外部からのコマンド実行を受け付けたいジョブ側で、事前に割り込みを許可するAPIを実行しておく必要があります。

    ----- CL2サンプル -----------------------------
    PGM
    DCL VAR(&CURSTAT)  TYPE(*CHAR) LEN(1)
    DCL VAR(&NEWSTAT)  TYPE(*CHAR) LEN(1)   VALUE('1')
    DCL VAR(&ERRCODE)  TYPE(*CHAR) LEN(8)
    CHGVAR VAR(%BIN(&ERRCODE 1 4)) VALUE(0)
    CHGVAR VAR(%BIN(&ERRCODE 5 4)) VALUE(0)
    CALL PGM(QSYS/QWCCJITP) PARM(&CURSTAT &NEWSTAT &ERRCODE)
    ENDPGM
    --------------------------------------------------

    実行例:CALL QGPL/ALW_INTJOB
    (※こちらも事前にライブラリーリストに入っているLIBへコンパイルしておきます)

  4. 割り込みを指示するCLの作成と実行(CL3:SETLIB_APT)

    操作中の別端末から、対象ジョブに割り込み実行を指示するためのCLを作成します。

    ----- CL3サンプル -----------------------------
    PGM
    DCL VAR(&INPUT)    TYPE(*CHAR) LEN(56)
    DCL VAR(&FORMAT)   TYPE(*CHAR) LEN(8)   VALUE('JITP0100')
    DCL VAR(&ERRCODE)  TYPE(*CHAR) LEN(8)
    CHGVAR VAR(%SST(&INPUT 1 10))  VALUE('SETLIB_T  ')
    CHGVAR VAR(%SST(&INPUT 11 10)) VALUE('QGPL      ')
    CHGVAR VAR(%SST(&INPUT 21 10)) VALUE('JOB_NAME  ')
    CHGVAR VAR(%SST(&INPUT 31 10)) VALUE('USR_NAME  ')
    CHGVAR VAR(%SST(&INPUT 41 6))  VALUE('123456')
    CHGVAR VAR(%SST(&INPUT 47 2))  VALUE(X'0000')
    CHGVAR VAR(%BIN(&INPUT 49 4))  VALUE(0)
    CHGVAR VAR(%BIN(&INPUT 53 4))  VALUE(0)
    CHGVAR VAR(%BIN(&ERRCODE 1 4)) VALUE(0)
    CHGVAR VAR(%BIN(&ERRCODE 5 4)) VALUE(0)
    CALL PGM(QSYS/QWCJBITP) PARM(&INPUT &FORMAT &ERRCODE)
    ENDPGM
    --------------------------------------------------
    

    【設定のポイント】

    • 『CHGVAR VAR(%SST(&INPUT 1 10)) VALUE('SETLIB_T ')』はCL1のプログラム名です。
    • 『CHGVAR VAR(%SST(&INPUT 11 10)) VALUE('QGPL ')』はコンパイル先のライブラリー名です。
    • 『CHGVAR VAR(%SST(&INPUT 21 10)) VALUE('JOB_NAME ')』は対象ジョブの「ジョブ名」を指定します。
    • 『CHGVAR VAR(%SST(&INPUT 31 10)) VALUE('USR_NAME ')』は対象ジョブの「ユーザー名」を指定します。
    • 『CHGVAR VAR(%SST(&INPUT 41 6)) VALUE('123456')』は対象ジョブの「ジョブ番号(6桁固定)」を指定します。


VALUEの値の指定は桁数が固定されています。

指定値が桁数に満たない場合は、半角スペースで埋めて桁数を合わせてください。

プログラムを任意の場所にコンパイルし、権限の高いユーザーでサインオンしてこのCL3をCALLすると、指定したジョブ情報を持つジョブに割り込んでCL1(ADDLIBLEコマンド)を実行させることができます。

これを利用すれば、ジョブ名や実行させたいコマンド(CHGLIBLやOVRDBFなど)を画面から動的に受け取ってAPIに渡すような「ジョブ割り込みユーティリティ」を作ることも理論上は可能です。

IBM i (AS/400)のディープな仕組みを知る上での技術的な知見として留めていただき、本番環境のシステム値や出口ポイントのセキュリティ設計を点検する契機としてご活用いただければ幸いです。

by . 大熊猫橋

あわせて読みたい記事

PAGE TOP